Relation between Simple Harmonic Motion and Uniform Circular Motion

phasor[A_, ω_, ϕ_, t_] := {A  Cos[ω t + ϕ], A  Sin[ω t + ϕ]}

max = 1.1;
p1[t_] := phasor[1, 1, 0, t];
all = Table[{t, p1[t][[1]]}, {t, 0, 8π, π/50}];

Animate[GraphicsRow[{
Graphics[{
Point[{0,0}], (* Dot at origin *)
{Dotted, Line[{{-1, 0}, {1, 0}}]},
{Dotted, Line[{{0, -1}, {0, 1}}]},
Arrow[{{0,0}, p1[t]}], (* Vector from origin to end of p1 *)
{Dashed, Line[{{p1[t][[1]], 0}, p1[t]}]}, (* Vertcal line showing x projection of p1 *)
{Dashed, Line[{{0, 0}, {p1[t][[1]], 0}}]}, (* Horizontal line showing x component of p1 *)
{Red, PointSize[0.02], Point[{p1[t][[1]], 0}]} (* x-component only *)
},
AspectRatio->1,PlotRange->{{-max, max}, {-max, max}}],ListPlot[{all, {{t, p1[t][[1]]}}}, Joined->{True, False},PlotStyle->{Blue, {Red, PointSize[0.025]}}, LabelStyle -> Larger]
}, ImageSize-> Scaled[0.8]], {t, 0, 8π, π/50.0}, DefaultDuration -> 20, DisplayAllSteps -> True, AnimationRunning->False]

Consider the vector of length A at an angle θ.  Assume that the vector rotates at constant angular velocity so that θ = ω t.  The x-component of that vector is then 
x = A cos(θ) = A cos(ω t).