Wave Motion

Motion of a Generic Pulse

f1[x_] := 1/((((x+3))^2) + 1)

Plot[f1[x], {x, -8, 8}]

The generic form for a traveling wave moving to the right is f(x - vt).

f1[x-vt]

Make the pulse move with speed v = 2.

Animate[Plot[f1[x-2 t], {x, -10, 10}, PlotRange->{0, 1}, PlotLabel -> PaddedForm[t, {5, 2}]], {t, 0, 10, 0.1}, AnimationRunning->False]

Motion of a Periodic Wave

Clear[λ, f2, v]
λ = 4; v = 2;

Plot[Cos[((2 π)/λ) x], {x, -10, 10}, LabelStyle->Larger, AxesLabel->{"x", "y(x, t)"}]

We can also compare the wave at two different times, say 0.0 and 0.4 seconds:

Plot[{Cos[((2 π)/λ) (x - v*0)],Cos[((2 π)/λ) (x- v*(0.4))]}, {x, -10, 10}, PlotLegends -> {"t=0.0", "t=0.4"}, LabelStyle->Larger, AxesLabel->{"x", "y(x, t)"}]

Animate[Plot[Cos[((2 π)/λ)(x - v t)], {x, -10, 10}, LabelStyle->Larger, AxesLabel->{"x", "y(x, t)"},PlotRange->{-1, 1}, PlotLabel->PaddedForm[t, {5, 2}], ImageSize->Scaled[0.75]], {t, 0, 5,0.1}, AnimationRate-> .5, AnimationRunning->False]

Now look at a fixed point in space (say x == 5) and ask what the wave does at that point.

v = 2;
Manipulate[Show[{Plot[Cos[((2 π)/λ)(x-v t)], {x, -10, 10}, LabelStyle->Larger, AxesLabel->{"x", "y(x, t)"}, PlotRange->{-1, 1}, PlotLabel -> PaddedForm[t, {5, 2}]], Graphics[{Red, Disk[{5, Cos[((2 π)/λ)(5 - v t)]}, {0.4,0.08}]}]},
ImageSize -> Scaled[0.8]], {t, 0, 25,0.01, Appearance -> "Open", AnimationRate -> 0.5, AnimationRunning-> False}]

It exhibits periodic motion, with a time T = λ/v.

T = λ/v