A comparison of θ and Sin[θ]

err[θ_] := 100 * (θ - Sin[θ])/Sin[θ]

findangle[tol_] := FindRoot[err[θ] == tol, {θ, 1}][[1,2]] /°

Plot[{θ, Sin[θ]}, {θ, 0, π/2}, PlotLegends -> "Expressions", LabelStyle -> Larger, AxesLabel -> {"θ", None}, ImageSize-> Scaled[0.80]]

Plot[err[θ °], {θ, 0, 90}, PlotLabel -> "Percent Error", LabelStyle -> Larger,  AxesLabel -> {"θ (degrees)", "Percent Error"}, ImageSize -> Scaled[0.80]]

Style[TableForm[Table[{tol, findangle[tol]}, {tol, {10, 1, 0.1, 0.01, 0.001, 0.0001}}],TableHeadings -> {None, {"Percent Error", "Angle (Degrees)"}}], Large]

If you have a pendulum clock and want to be off by at most one minute at the end of the day, the relative accuracy is then:

60/86400.

which corresponds to an angle of less than 0.37 degrees:

findangle[%]

Application to Lab

Is the pendulum a simple harmonic oscillator?  Does the period depend on amplitude?  Measure the period (and its uncertainty) for a range of amplitudes.  Enter the data in 3 columns:  Amplitude, Period, and uncertainty in Period:

data = (({{1.372, 1.109, 0.0023}, {2.254, 1.423, 0.0061}, {1.729, 1.2, .0026}, {0.5828, 1.005, 0.0007}, {.2793, .9853, .0006}, {2.000, 1.322, .005}, {.4912, .9966, .0006}, {1.091, 1.061, .00099}, {1.831, 1.228, .003}, {.6731, 1.012, .0006}, {.253, .9851, .00066}}));

pdata = Sort[Map[{#[[1]], Around[#[[2]], #[[3]]]} &, data]](* Data for plot *);

Style[TableForm[pdata, TableHeadings -> {None, {"Amp (rad)", "Period (s)", "Uncertainty (s)"}}], Large]

Zooming in on the first few points, we see that the variations are much larger than the uncertainties.

dataplot = ListPlot[pdata[[Range[5]]], PlotStyle -> Red, AxesLabel -> {"Amplitude (radians)", "Period (s)"}, LabelStyle -> Larger, ImageSize -> Scaled[0.75]]

Looking at all the data, we can compare to a first-order correction and to an exact solution involving elliptic integrals

Tfull[θ_] := ((2 )/π)EllipticK[((Sin[(θ/2)])^2)]

dataplot = ListPlot[pdata, PlotStyle -> Red, AxesLabel -> {"Amplitude (radians)", "Period (s)"}, LabelStyle -> Larger, ImageSize -> Scaled[0.75]];

ndata = Map[{#[[1]], #[[2]]["Value"]} &, pdata] (* Data for fit *);
weights = Map[1/#[[2]]["Uncertainty"]^2 &, pdata];
fit = LinearModelFit[ndata, {1, Sin[θ/2]^2}, θ, Weights->weights];

Show[{dataplot,
Plot[{ndata[[1, 2]] * (1 + (1/(2^2))((Sin[(θ/2)])^2)),
ndata[[1, 2]] *Tfull[θ]}, {θ, 0, Max[data[[All, 1]]]},
PlotLegends->{"First Order Correction", "Full Theory"}]}]
fit["ParameterConfidenceIntervalTable"]

If you have a pendulum clock and want to be off by at most one minute at the end of the day, the relative accuracy is then (60/86400) which corresponds to an angle of about 6°.

FindRoot[Tfull[θ °] - 1 == 60/86400, {θ, 1}] // Quiet